build.gradle

plugins {
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.minecraftforge.gradle' version '[6.0,6.2)'
}

ext.buildnumber = 'DEV'
if (System.getenv('BUILD_NUMBER') != null)
    project.buildnumber = System.getenv('BUILD_NUMBER')
else
    logger.lifecycle "No build number detected, setting to DEV"

group = "com.theprogrammingturkey.chancecubes"
base {
    archivesName = "ChanceCubes"
}
version = "${mc_version}-${mod_version}.${buildnumber}"

java.toolchain.languageVersion = JavaLanguageVersion.of(17)
tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

minecraft {
    mappings channel: 'official', version: "${mc_version}"
    copyIdeResources = true
    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    // default run configurations.
    // these can be tweaked, removed, or duplicated as needed.
    runs {
        client {
            workingDirectory project.file('run-1.20')

            // Recommended logging data for a userdev environment
            property 'forge.logging.markers', ''

            // Recommended logging level for the console
            property 'forge.logging.console.level', 'info'

            mods {
                chancecubes {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run-server-1.20')

            // Recommended logging data for a userdev environment
            property 'forge.logging.markers', ''

            // Recommended logging level for the console
            property 'forge.logging.console.level', 'info'

            mods {
                chancecubes {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run-1.20')

            // Recommended logging data for a userdev environment
            property 'forge.logging.markers', ''

            // Recommended logging level for the console
            property 'forge.logging.console.level', 'info'

            args '--mod', "chancecubes", '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')

            mods {
                chancecubes {
                    source sourceSets.main
                }
            }
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    maven { url 'https://maven.mcmoddev.com' }
    maven { url 'https://www.dogforce-games.com/maven/' }
}

dependencies {
    minecraft "net.minecraftforge:forge:${mc_version}-${forge_version}"
}

jar {
    manifest {
        attributes(["Specification-Title"     : "chance_cubes",
                    "Specification-Vendor"    : "turkeydev",
                    "Specification-Version"   : "1", // We are version 1 of ourselves
                    "Implementation-Title"    : project.name,
                    "Implementation-Version"  : "${version}",
                    "Implementation-Vendor"   : "turkeydev",
                    "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")],)
    }
}