model.nlogo

extensions [array]
breed[people person]

people-own[
  groupType ;Is the agent of group A, B or C?
  credence ;This encodes this agent's credence about phi.
  bias ;This incodes the individual bias of this particular agent.
  expectedPatchConsensus ;The expected patch-consensus is calculated in round one, based on the identity of the other players.
  expectedDivergence ;Expected divergence is calculated in round one, based on the expected patch-consensus.
  testimony ;Testimony is given in round two and visible to other agents.
  ;*********************************************************************************************************************
  ;learning function
  averageTestimonies ;the average testimony given by members of this group to the agent
  encounters  ;the number of testimonies from these groups ;is there something wrong?
  quietingCount ;how often - per group - has this agent been quietened?
 ]

globals[
  phi ;value of the standpoint epistemological proposition that agents have credences about
  countAgents ;total number of agents in the simulation
  ;*********************************************************************************************************************
  ; groups 0 (A) , 1 (B) and 2 (C) (3 is (if applicable) the total of all groups)
  groupBiases
  groupColors
  groupCredences
  groupTestimonies
  groupPercentages ;How many percent of all agents are in groups A, B and C.
  groupCounts
  ;*********************************************************************************************************************
  ;Values for plotting and updating the outputs
  meanDistance ;How far - on average - are agents from the truth?
  smotheringCounter ;How often did agents succumb to smothering this round?
  quietingCounter ;how often did agents quieten others this round?
  smotheringCounterTotals ;How often did agents succumb to smothering in total?
  quietingCounterTotals ;How often did agents quieten others in total?
  ;*********************************************************************************************************************
  ;Metacredences about the three groups of agents
  credencesAboutA
  credencesAboutB
  credencesAboutC
 ]

to setup ;called at the start of each simulation
  clear-all
  reset-ticks
  setupWorld
  setupAgents
  prepareGame
  printSetup
  end

to go ;called once per tick
  ifelse allowInjustice = true [playGame][skipGame]
  if experiments = true [doExperiments]
  prepareGame
  if printUpdates? = TRUE [printUpdate]

  if (ticks >= numberOfTicks) OR (meanDistance < stopAtMeanErrorOf)[
    printUpdate
    stop
  ]
  tick
end

to playGame
  ;One game per patch:
  ask patches [
    ;Determine the players
    let players turtles-here
    let countplayers array:from-list (list (count turtles-here with [groupType = 0]) (count turtles-here with [groupType = 1]) (count turtles-here with [groupType = 2]) (count players))


    if array:item countplayers 3 > 1 [ ;no solo-games
      ;***************************************************************************************************************
      ;Round one
      ask players[
        calculateExpectedPatchConsensus self countplayers
        calculateExpectedDivergence
      ]


      ;***************************************************************************************************************
      ;Round two
      ask players[
        let expectedUtility (calculateExpectedUtility self countplayers)

        ifelse expectedUtility > utilitySmothering [;the bigger the value, the worse
          smother self
        ][
          set testimony credence ;give 'naive' testimony
        ]
      ]
      let patchConsensus calculatePatchConsensus players countplayers


      ;***************************************************************************************************************
      ;Round three
      ask players [
        let inputFromThisGame (calculateInput self countPlayers players patchConsensus)
        set credence (inputFromThisGame * weightOfInput) + (credence * (1 - weightOfInput))
      ]

    ]
  ]
end

to doExperiments ;agents slowly get closer to the truth on their own
  ask people[
    if biasType = "perpetual" [set credence (w * (phi + bias) + (1 - w) * credence)]

    if biasType = "resolving"  [

      let r random-float 2
      let delta (abs (credence - phi))
      set credence (w * (phi + delta * bias) + (1 - w) * credence)
    ]

    if biasType = "none" [
      set credence (w * phi + (1 - w) * credence)
    ]
  ]
end

to skipGame ;if the simulation disallows testimonial injustice, everyone just updates by splitting the difference with the mean of the other players
  ask patches [
    let players turtles-here
    let countplayers count players

    ask players[
      let input 0
      if countplayers > 1 [
        ask other players[
          set testimony credence
          ask myself [
            set input input + [testimony] of myself
          ]
        ]
        set input input / (countplayers - 1)
        set credence (input * weightOfInput) + (credence * (1 - weightOfInput));update credence after collecting all the input from the game
      ]
    ]
  ]
end

to setupAgents
  set groupColors array:from-list (list orange blue brown)
  set groupBiases array:from-list (list biasTypeA biasTypeB biasTypeC)
  set groupCounts array:from-list (list countTypeA countTypeB countTypeC)
  set countAgents array:item groupCounts 0 + array:item groupCounts 1 + array:item groupCounts 2
  set groupPercentages array:from-list (list ((countTypeA / countAgents) * 100) ((countTypeB / countAgents) * 100) ((countTypeC / countAgents) * 100))

  foreach [0 1 2] [
    x ->

    let counter array:item groupCounts x

    while [counter > 0] [
      set counter counter - 1
      create-people 1[
        ;-----------------------------------------------------------------------------------------------------
        ;basic features
        set xcor random-xcor
        set ycor random-ycor
        set heading random 360
        set shape "person"
        set size 0.3
        ;-----------------------------------------------------------------------------------------------------
        ;group specific features
        set bias (random-float 2.2 * (array:item groupBiases x) - (0.1 * array:item groupBiases x)) ;some people are outliers in their group!

        ;Coudld be used to disallows too-far-gones
        ; if (bias > 1)[set bias 1]
        ; if (bias < -1)[set bias -1]

        set credence phi + bias + (random-float 0.4 - 0.2)
        set groupType x
        set color array:item groupColors x
        set expectedDivergence array:from-list (list 0 0 0 0)
        ;-----------------------------------------------------------------------------------------------------
        ;learning function features
        set quietingCount array:from-list (list 0 0 0 0)
        set encounters array:from-list (list 0 0 0)
        set averageTestimonies array:from-list (list  random-float 1  random-float 1  random-float 1) ;random priors
      ]
    ]
  ]
end

to setupWorld
  resize-world (0 -(worldDimensions / 2)) (worldDimensions / 2) (0 -(worldDimensions / 2)) (worldDimensions / 2)
  set-patch-size 450 / (worldDimensions + 1)
  ask patches [ ;checkerboard coloring
    ifelse (((pxcor + pycor) mod 2) = 0)[
      set pcolor grey
    ][
      set pcolor white
    ]
  ]
 ifelse staticPhi? = TRUE [
      set phi staticPhi
    ][
      set phi random-float 1
    ]
  set quietingCounterTotals array:from-list (list 0 0 0 0)
  set smotheringCounterTotals array:from-list (list 0 0 0 0)
end

to prepareGame ;agents move, group credences, testimony and distance from the truth are updatedphi
  resetValues

  ; Update the all-groups totals of quieting and smothering
  array:set quietingCounterTotals 3 (array:item quietingCounterTotals 0 + array:item quietingCounterTotals 1 + array:item quietingCounterTotals 2)
  array:set smotheringCounterTotals 3 (array:item smotheringCounterTotals 0 + array:item smotheringCounterTotals 1 + array:item smotheringCounterTotals 2)
  let NAcounter array:from-list (list 0 0 0)

  ask people[
    if credence > 1 [set credence 1] ;just in case
    if credence < 0 [set credence 0]
    forward random 10
    left (random 10) - 5
    set meanDistance meanDistance + abs (phi - credence)

    array:set groupCredences groupType (array:item groupCredences groupType + credence)

    ifelse testimony = "NA"[
      array:set NAcounter [grouptype] of self ((array:item NAcounter [grouptype] of self) + 1)
    ][
      array:set groupTestimonies groupType (array:item groupTestimonies groupType + testimony)
    ]

    ;update the metacredences
    array:set credencesAboutA groupType (array:item credencesAboutA groupType + array:item averageTestimonies 0)
    array:set credencesAboutB groupType (array:item credencesAboutB groupType + array:item averageTestimonies 1)
    array:set credencesAboutC groupType (array:item credencesAboutC groupType + array:item averageTestimonies 2)

  ]

  foreach [0 1 2] [
    x ->
    if array:item groupCounts x > 0 [
      array:set groupCredences x (array:item groupCredences x / array:item groupCounts x)

      if ((array:item groupCounts x - array:item NAcounter x) > 0)[
        array:set groupTestimonies x (array:item groupTestimonies x / (array:item groupCounts x - array:item NAcounter x))]


      array:set credencesAboutA x (array:item credencesAboutA x / array:item groupCounts x)
      array:set credencesAboutB x (array:item credencesAboutB x / array:item groupCounts x)
      array:set credencesAboutC x (array:item credencesAboutC x / array:item groupCounts x)
    ]
  ]

  set meanDistance meanDistance / countAgents

end

to resetValues
  set groupCredences array:from-list (list 0 0 0)
  set groupTestimonies array:from-list (list 0 0 0)
  set credencesAboutA array:from-list (list 0 0 0)
  set credencesAboutB array:from-list (list 0 0 0)
  set credencesAboutC array:from-list (list 0 0 0)
  set meanDistance 0
  set quietingCounter 0
  set smotheringCounter 0
end

to printUpdate
  print "--------------------------------------------------------------------------------------"
  print(word "After round " ticks " the average credence in P is " (precision (array:item groupCredences 0) 3) " for group A, " (precision (array:item groupCredences 1) 3) " for group B, and " (precision (array:item groupCredences 2) 3) " for group C.")
  print(word "The average testimony given by members of group A is " (precision (array:item groupTestimonies 0) 3) ", while for members of group B it is " (precision (array:item groupTestimonies 1) 3) " and for members of group C it is " (precision (array:item groupTestimonies 2) 3) ".")
  print(word "The mean distance from the truth for the whole population of agents is currently " (precision meanDistance 3) ".")
  print(word "This round " smotheringCounter " agents tailored their testimony (total of " array:item smotheringCounterTotals 3 ") , and  " quietingCounter " individual instances of quieting were committed (total of " array:item quietingCounterTotals 3").")
end

to printSetup
  print "--------------------------------------------------------------------------------------"
  print "--------------------------------------------------------------------------------------"
  print "--------------------------------------------------------------------------------------"
  print(word "New simulation started @ "date-and-time)
  print(word "In this simulation the objective value of the proposition is " (precision phi 3) ".")
  print (word "It contains " countAgents " agents, " (precision (array:item groupPercentages 0) 1) "% group A, " (precision (array:item groupPercentages 1) 1) "% group B and " (precision (array:item groupPercentages 2) 1) "% group C.")
  print(word "The average credence in P is " (precision (array:item groupCredences 0) 3) " for group A, " (precision (array:item groupCredences 1) 3) " for group B, and " (precision (array:item groupCredences 2) 3) " for group C.")
  print(word "The mean distance from the truth for the whole population of agents starts at " (precision meanDistance 3) ".")
end

to-report shouldQuieten? [aggressor victim patchConsensus countplayers]
  ;---------------------------------------------------------------------------------------------------
  ;If smothering results in a refusal to speak at all, then there is no testimony to be quietened.
  if [testimony] of victim = "NA" [
        report FALSE
  ]
  ;---------------------------------------------------------------------------------------------------
  let divergenceAggressorConsensus abs ([credence] of aggressor - patchConsensus)
  let divergenceVictimConsensus abs ([testimony] of victim - patchConsensus)
  let divergenceVictimAggressor abs ([testimony] of victim - [credence] of aggressor)

  ;conditions for quieting:
  ifelse ([groupType] of aggressor != [groupType] of victim) ; 1: different group identities
  AND divergenceAggressorConsensus < divergenceVictimConsensus ; 2: credence of aggressor is closer to the group consensus than testimony of victim
  AND divergenceVictimAggressor > quietenThreshold ; 3: testimony of victim is far enough from credence of aggressor
  AND divergenceVictimConsensus > quietenThreshold ; 4: testimony of victim is far enough from the patch consensus
  AND  (array:item countplayers [groupType] of aggressor) > (array:item countplayers [groupType] of victim) ;aggressor's group is in the majority compared to the victim's group
  [report true][report false]
end

to smother [agent] ;give tailored testimony/ withold testimony
  ask agent [
    if  smotheringType = "compromise"[
      set testimony ((credence + expectedPatchConsensus) / 2)
    ]
    if smotheringType = "tailor" [
      set testimony expectedPatchConsensus
    ]
    if smotheringType = "withhold"[
      set testimony "NA"
    ]

    set smotheringCounter smotheringCounter + 1
    array:set smotheringCounterTotals groupType (array:item smotheringCounterTotals groupType + 1)
    ]
end

to calculateExpectedPatchConsensus [agent countplayers]
  let result 0

  ask agent [

    ;Are agents using their subjective metacredences or the objective mean credences?
    let data 0
    ifelse learningOption = TRUE [set data averageTestimonies][set data groupCredences]

    ;Are agents calculating the expected patch-consensus with, or without their own credence added to the pool?
    if patchConsensusType = "include own credence" [
      if groupType = 0 [set result (credence + (array:item countplayers 0 - 1) * array:item data 0 + (array:item countplayers 1) * (array:item data 1) + array:item countplayers 2 * array:item data 2)]
      if groupType = 1 [set result (credence + (array:item countplayers 0) * array:item data 0 + (array:item countplayers 1 - 1) * (array:item data 1) + (array:item countplayers 2 * array:item data 2))]
      if groupType = 2 [set result (credence + (array:item countplayers 0) * array:item data 0 + (array:item countplayers 1) * (array:item data 1) + (array:item countplayers 2 - 1) * array:item data 2)]
      set result result / (array:item countplayers 3)
    ]

    if patchConsensusType = "omit own credence" [
      if groupType = 0 [set result ((array:item countplayers 0 - 1) * (array:item data 0) + (array:item countplayers 1) * (array:item data 1) + (array:item countplayers 2) * (array:item data 2))]
      if groupType = 1 [set result ((array:item countplayers 0) * (array:item data 0) + (array:item countplayers 1 - 1) * (array:item data 1) + (array:item countplayers 2) * (array:item data 2))]
      if groupType = 2 [set result ((array:item countplayers 0) * (array:item data 0) + (array:item countplayers 1) * (array:item data 1) + (array:item countplayers 2 - 1) * (array:item data 2))]
      set result result / ((array:item countplayers 3) - 1)
    ]
    set expectedPatchConsensus result
  ]
end

to-report calculatePatchConsensus [players countplayers]
  let result 0
  let relevantplayerCount array:item countplayers 3
  ask players [
    ifelse testimony = "NA"[
      set relevantplayerCount relevantplayerCount - 1
    ][
    set result result + testimony
    ]
  ]
  set result result / relevantplayerCount
  report result
end

to-report calculateExpectedUtility [agent countplayers] ;calculated in round 2 of each game, based the quieting conditions

  let expectedUtility 0

  ask agent[
    if (requireExperience = FALSE) OR (array:item quietingCount 3 > 0)[;if we require experience AND have none, we skip this calculation

      if (array:item expectedDivergence 3 > quietenThreshold)[;the agent is only in danger, if their expect to be far from the patch-consensus, and then for each group, if they expect to be far from the credence of its members
        if groupType = 0[
          if ((array:item countplayers 0) < (array:item countplayers 1)) AND (array:item expectedDivergence 1 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 1) * utilityQuieting]
          if ((array:item countplayers 0) < (array:item countplayers 2)) AND (array:item expectedDivergence 2 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 2) * utilityQuieting]
        ]

        if groupType = 1[
          if ((array:item countplayers 1) < (array:item countplayers 0)) AND (array:item expectedDivergence 0 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 0) * utilityQuieting]
          if ((array:item countplayers 1) < (array:item countplayers 2)) AND (array:item expectedDivergence 2 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 2) * utilityQuieting]
        ]

        if groupType = 2[
          if ((array:item countplayers 2) < (array:item countplayers 0)) AND (array:item expectedDivergence 0 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 0) * utilityQuieting]
          if ((array:item countplayers 2) < (array:item countplayers 1)) AND (array:item expectedDivergence 1 > quietenThreshold)[set expectedUtility expectedUtility + (array:item countplayers 1) * utilityQuieting]
        ]
      ]
    ]
  ]
  report expectedUtility
end

to calculateExpectedDivergence

  array:set expectedDivergence 3 abs (expectedPatchConsensus - credence)

  foreach [0 1 2] [
    x ->
    ifelse learningOption = TRUE [
      array:set expectedDivergence x abs (credence - array:item averageTestimonies x)
    ][
      array:set expectedDivergence x abs (credence - array:item groupCredences x)
    ]
  ]
end

to-report calculateInput [agent playerCount players patchConsensus]
  let inputFromThisGame 0 ;used to calculate the subjective mean testimony in the current game
  ask agent [
    let relevantplayerCount ((array:item playerCount 3) - 1); number of OTHER players
    ask other players[

      if learningOption = TRUE [ ;Updates the agents credences about the other players
        if [testimony] of self != "NA"[
          ask myself[
            array:set averageTestimonies ([groupType] of myself) ((array:item averageTestimonies ([groupType] of myself) * array:item encounters ([groupType] of myself) + [testimony] of myself) / (array:item encounters ([groupType] of myself) + 1))
            array:set encounters ([groupType] of myself) (array:item encounters ([groupType] of myself) + 1);the aggressor counts the encounter
          ]
        ]
      ]

      ifelse (shouldQuieten? myself self patchConsensus playerCount) = TRUE [

        ;(Victim) counts the quieting.
        array:set quietingCount 3 (array:item quietingCount 3 + 1)
        array:set quietingCount ([groupType] of myself) (array:item quietingCount ([groupType] of myself) + 1)
        set quietingCounter quietingCounter + 1
        array:set quietingCounterTotals groupType (array:item quietingCounterTotals groupType + 1)

        ;quietened players get ignored
        set relevantplayerCount relevantplayerCount - 1

      ][
        ifelse [testimony] of self = "NA" [;NA testimony is not added to the input
          set relevantplayerCount relevantplayerCount - 1
        ][
          ;non-quietened other players that gave testimony are added to the input of the agent
          set inputFromThisGame inputFromThisGame + [testimony] of self
        ]
      ]
    ]
    if relevantplayerCount > 0 [set inputFromThisGame inputFromThisGame / relevantplayerCount]
  ]
  report inputFromThisGame
end
@#$#@#$#@
GRAPHICS-WINDOW
5
10
463
469
-1
-1
90.0
1
10
1
1
1
0
1
1
1
-2
2
-2
2
0
0
1
ticks
30.0

SLIDER
634
508
828
541
countTypeA
countTypeA
1
200
200.0
1
1
NIL
HORIZONTAL

BUTTON
7
474
62
548
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
634
577
828
610
countTypeB
countTypeB
1
200
50.0
1
1
NIL
HORIZONTAL

SLIDER
634
542
828
575
biasTypeA
biasTypeA
-1
1
-0.9
0.01
1
NIL
HORIZONTAL

SLIDER
634
612
828
645
biasTypeB
biasTypeB
-1
1
0.0
0.1
1
NIL
HORIZONTAL

BUTTON
64
474
119
547
NIL
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

PLOT
1013
10
1266
256
Mean error
NIL
NIL
0.0
1.0
0.0
1.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot meanDistance"

PLOT
502
10
755
255
Mean credences
NIL
NIL
0.0
1.0
0.0
1.0
true
false
";set groupCredences array:from-list (list 0 0 0)" ""
PENS
"default" 1.0 0 -16777216 true "" "ifelse staticPhi? = TRUE [plot staticPhi][plot phi]"
"Group A" 1.0 0 -955883 true "" "plot array:item groupCredences 0"
"Group B" 1.0 0 -13345367 true "" "plot array:item groupCredences 1"
"Group C" 1.0 0 -6459832 true "" "plot array:item groupCredences 2"

SWITCH
1285
508
1522
541
learningOption
learningOption
0
1
-1000

SLIDER
1076
581
1260
614
utilityQuieting
utilityQuieting
0
10
2.0
1
1
NIL
HORIZONTAL

SLIDER
1076
617
1260
650
utilitySmothering
utilitySmothering
0
10
3.0
1
1
NIL
HORIZONTAL

SLIDER
8
612
175
645
worldDimensions
worldDimensions
0
10
4.0
2
1
NIL
HORIZONTAL

PLOT
757
10
1011
255
Mean testimonies
NIL
NIL
0.0
1.0
0.0
1.0
true
false
";set groupTestimonies array:from-list (list 0 0 0)" ""
PENS
"default" 1.0 0 -16777216 true "" "plot phi"
"Group A" 1.0 0 -955883 true "" "plot array:item groupTestimonies 0"
"Group B" 1.0 0 -13345367 true "" "plot array:item groupTestimonies 1"
"Group C" 1.0 0 -6459832 true "" "plot array:item groupTestimonies 2"

SLIDER
634
682
829
715
biasTypeC
biasTypeC
-1
1
0.5
0.1
1
NIL
HORIZONTAL

SWITCH
1076
509
1260
542
allowInjustice
allowInjustice
0
1
-1000

BUTTON
121
474
176
547
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

CHOOSER
1076
652
1261
697
smotheringType
smotheringType
"tailor" "compromise" "withhold"
0

SWITCH
869
509
1051
542
experiments
experiments
0
1
-1000

CHOOSER
288
586
494
631
patchConsensusType
patchConsensusType
"omit own credence" "include own credence"
0

PLOT
502
257
755
503
Mean # of quietings
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"set quietingCounterTotals array:from-list (list 0 0 0 0)\nset countAgents (countTypeA + countTypeB + countTypeC)" ""
PENS
"Total" 1.0 0 -16777216 true "" "plot array:item quietingCounterTotals 3 / countAgents"
"Group A" 1.0 0 -955883 true "" "plot array:item quietingCounterTotals 0 / countTypeA"
"Group B" 1.0 0 -13345367 true "" "plot array:item quietingCounterTotals 1 / countTypeB"
"Group C" 1.0 0 -6459832 true "" "if countTypeC > 0 [plot array:item quietingCounterTotals 2 / countTypeC]"

PLOT
759
256
1012
501
Mean # of smotherings
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"set smotheringCounterTotals array:from-list (list 0 0 0 0)\nset countAgents (countTypeA + countTypeB + countTypeC)\n" ""
PENS
"Total" 1.0 0 -16777216 true "" "plot array:item smotheringCounterTotals 3 / countAgents"
"Group A" 1.0 0 -955883 true "" "plot array:item smotheringCounterTotals 0 / countTypeA"
"Group B" 1.0 0 -13345367 true "" "plot array:item smotheringCounterTotals 1 / countTypeB"
"Group C" 1.0 0 -6459832 true "" "if countTypeC > 0 [plot array:item smotheringCounterTotals 2 / countTypeC]"

SWITCH
288
478
464
511
staticPhi?
staticPhi?
0
1
-1000

SLIDER
288
632
465
665
weightOfInput
weightOfInput
0.01
0.99
0.1
0.01
1
NIL
HORIZONTAL

PLOT
1013
256
1266
501
Metacredences about A
NIL
NIL
0.0
10.0
0.0
1.0
true
false
"" ""
PENS
"Actual Value" 1.0 0 -16777216 true "" "plot array:item groupCredences 0"
"group A" 1.0 0 -955883 true "" "plot array:item credencesAboutA 0"
"group B" 1.0 0 -13345367 true "" "plot array:item credencesAboutA 1"
"group C" 1.0 0 -6459832 true "" "plot array:item credencesAboutA 2"

PLOT
1268
257
1522
503
Metacredences about B
NIL
NIL
0.0
10.0
0.0
1.0
true
false
"" ""
PENS
"Actual Value" 1.0 0 -16777216 true "" "plot array:item groupCredences 1"
"group A" 1.0 0 -955883 true "" "plot array:item credencesAboutB 0"
"group B" 1.0 0 -13345367 true "" "plot array:item credencesAboutB 1"
"group C" 1.0 0 -6459832 true "" "plot array:item credencesAboutB 2"

PLOT
1268
10
1518
255
Metacredences about C
NIL
NIL
0.0
10.0
0.0
1.0
true
false
"" ""
PENS
"Actual Value" 1.0 0 -16777216 true "" "plot array:item groupCredences 2"
"Group A" 1.0 0 -955883 true "" "plot array:item credencesAboutC 0"
"Group B" 1.0 0 -13345367 true "" "plot array:item credencesAboutC 1"
"Group C" 1.0 0 -6459832 true "" "plot array:item credencesAboutC 2"

SWITCH
8
647
175
680
PrintUpdates?
PrintUpdates?
1
1
-1000

SLIDER
869
544
1051
577
w
w
0.01
0.1
0.1
0.01
1
NIL
HORIZONTAL

CHOOSER
869
579
1051
624
biasType
biasType
"resolving" "none" "perpetual"
0

INPUTBOX
8
551
176
611
numberOfTicks
3000.0
1
0
Number

SLIDER
1076
545
1260
578
quietenThreshold
quietenThreshold
0
1
0.1
0.1
1
NIL
HORIZONTAL

SLIDER
634
647
829
680
countTypeC
countTypeC
0
200
0.0
10
1
NIL
HORIZONTAL

SLIDER
288
515
465
548
staticPhi
staticPhi
0
1
1.0
0.05
1
NIL
HORIZONTAL

SWITCH
1285
544
1522
577
requireExperience
requireExperience
1
1
-1000

SLIDER
288
551
465
584
stopAtMeanErrorOf
stopAtMeanErrorOf
0
0.2
0.0
0.01
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

(a general understanding of what the model is trying to show or explain)

## HOW IT WORKS

(what rules the agents use to create the overall behavior of the model)

## HOW TO USE IT

(how to use the model, including a description of each of the items in the Interface tab)

## THINGS TO NOTICE

(suggested things for the user to notice while running the model)

## THINGS TO TRY

(suggested things for the user to try to do (move sliders, switches, etc.) with the model)

## EXTENDING THE MODEL

(suggested things to add or change in the Code tab to make the model more complicated, detailed, accurate, etc.)

## NETLOGO FEATURES

(interesting or unusual features of NetLogo that the model uses, particularly in the Code tab; or where workarounds were needed for missing features)

## RELATED MODELS

(models in the NetLogo Models Library and elsewhere which are of related interest)

## CREDITS AND REFERENCES

(a reference to the model's URL on the web if it has one, as well as any other necessary credits, citations, and links)
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.1.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@